Rules for integrands of the form(((a+b Sec[c+d (x^n)]))^p)

1:  ∫(((a+b Sec[c+d (x^n)]))^p)dx  when (1/n)∈(SuperPlus[ℤ])∧ p∈ℤ

Derivation: Integration by substitution

Basis: If  -1≤n≤1 ∧ n≠0, then F[(x^n)]==(1/n) Subst[(x^((1/n)-1))F[x],x,(x^n)] (∂_x)(x^n)

Note: If (1/n)∈(SuperMinus[ℤ]), resulting integrand is not integrable.

Rule: If (1/n)∈(SuperPlus[ℤ])∧ p∈ℤ, then

∫(((a+b Sec[c+d (x^n)]))^p)dx  ⟶  (1/n) Subst[∫(x^((1/n)-1)) (((a+b Sec[c+d x]))^p)dx,x,(x^n)]

Program code:

Int[(a_.+b_.*Sec[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(1/n-1)*(a+b*Sec[c+d*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,p},x] && IGtQ[1/n,0] && IntegerQ[p]

Int[(a_.+b_.*Csc[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(1/n-1)*(a+b*Csc[c+d*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,p},x] && IGtQ[1/n,0] && IntegerQ[p]

X:  ∫(((a+b Sec[c+d (x^n)]))^p)dx

Rule:

∫(((a+b Sec[c+d (x^n)]))^p)dx  ⟶  ∫(((a+b Sec[c+d (x^n)]))^p)dx

Program code:

Int[(a_.+b_.*Sec[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Unintegrable[(a+b*Sec[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,n,p},x]

Int[(a_.+b_.*Csc[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Unintegrable[(a+b*Csc[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,n,p},x]

S:  ∫(((a+b Sec[c+d (u^n)]))^p)dx  when  u==e+f x

Derivation: Integration by substitution

Rule: If  u==e+f x, then

∫(((a+b Sec[c+d (u^n)]))^p)dx  ⟶  (1/f)Subst[∫(((a+b Sec[c+d (x^n)]))^p)dx,x,u]

Program code:

Int[(a_.+b_.*Sec[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(a+b*Sec[c+d*x^n])^p,x],x,u] /;
FreeQ[{a,b,c,d,n,p},x] && LinearQ[u,x] && NeQ[u,x]

Int[(a_.+b_.*Csc[c_.+d_.*u_^n_])^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(a+b*Csc[c+d*x^n])^p,x],x,u] /;
FreeQ[{a,b,c,d,n,p},x] && LinearQ[u,x] && NeQ[u,x]

N:  ∫(((a+b Sec[u]))^p)dx  when  u==c+d (x^n)

Derivation: Algebraic normalization

Rule: If  u==c+d (x^n), then

∫(((a+b Sec[u]))^p)dx  ⟶  ∫(((a+b Sec[c+d (x^n)]))^p)dx

Program code:

Int[(a_.+b_.*Sec[u_])^p_.,x_Symbol] :=
  Int[(a+b*Sec[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Int[(a_.+b_.*Csc[u_])^p_.,x_Symbol] :=
  Int[(a+b*Csc[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Rules for integrands of the form(((e x))^m) (((a+b Sec[c+d (x^n)]))^p)

1.  ∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx

1:  ∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx  when ((m+1)/n)∈(SuperPlus[ℤ])∧ p∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Note: If ((m+1)/n)∈(SuperMinus[ℤ]), resulting integrand is not integrable.

Rule: If ((m+1)/n)∈(SuperPlus[ℤ])∧ p∈ℤ, then

∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((a+b Sec[c+d x]))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_.+b_.*Sec[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*Sec[c+d*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,m,n,p},x] && IGtQ[Simplify[(m+1)/n],0] && IntegerQ[p]

Int[x_^m_.*(a_.+b_.*Csc[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*Csc[c+d*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,m,n,p},x] && IGtQ[Simplify[(m+1)/n],0] && IntegerQ[p]

X:  ∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx

Rule:

∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx  ⟶  ∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx

Program code:

Int[x_^m_.*(a_.+b_.*Sec[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Unintegrable[x^m*(a+b*Sec[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x]

Int[x_^m_.*(a_.+b_.*Csc[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  Unintegrable[x^m*(a+b*Csc[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,m,n,p},x]

2:  ∫(((e x))^m) (((a+b Sec[c+d (x^n)]))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e x))^m)/(x^m))==0

Rule:

∫(((e x))^m) (((a+b Sec[c+d (x^n)]))^p)dx  ⟶  (((e^(IntPart[m])) (((e x))^(FracPart[m])))/(x^(FracPart[m]))) ∫(x^m) (((a+b Sec[c+d (x^n)]))^p)dx

Program code:

Int[(e_*x_)^m_.*(a_.+b_.*Sec[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Sec[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x]

Int[(e_*x_)^m_.*(a_.+b_.*Csc[c_.+d_.*x_^n_])^p_.,x_Symbol] :=
  e^IntPart[m]*(e*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(a+b*Csc[c+d*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x]

N:  ∫(((e x))^m) (((a+b Sec[u]))^p)dx  when  u==c+d (x^n)

Derivation: Algebraic normalization

Rule: If  u==c+d (x^n), then

∫(((e x))^m) (((a+b Sec[u]))^p)dx  ⟶  ∫(((e x))^m) (((a+b Sec[c+d (x^n)]))^p)dx

Program code:

Int[(e_*x_)^m_.*(a_.+b_.*Sec[u_])^p_.,x_Symbol] :=
  Int[(e*x)^m*(a+b*Sec[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,e,m,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Int[(e_*x_)^m_.*(a_.+b_.*Csc[u_])^p_.,x_Symbol] :=
  Int[(e*x)^m*(a+b*Csc[ExpandToSum[u,x]])^p,x] /;
FreeQ[{a,b,e,m,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

Rules for integrands of the form(x^m) ((Sec[a+b (x^n)])^p) Sin[a+b (x^n)]

1:  ∫(x^m) ((Sec[a+b (x^n)])^p) Sin[a+b (x^n)]dx  when  n∈ℤ ∧ m-n≥0 ∧ p≠1

Derivation: Integration by parts

Rule: If  n∈ℤ ∧ m-n≥0 ∧ p≠1, then

∫(x^m) ((Sec[a+b (x^n)])^p) Sin[a+b (x^n)]dx  ⟶  (((x^(m-n+1)) ((Sec[a+b (x^n)])^(p-1)))/(b n (p-1)))-((m-n+1)/(b n (p-1)))∫(x^(m-n)) ((Sec[a+b (x^n)])^(p-1))dx

Program code:

Int[x_^m_.*Sec[a_.+b_.*x_^n_.]^p_*Sin[a_.+b_.*x_^n_.],x_Symbol] :=
  x^(m-n+1)*Sec[a+b*x^n]^(p-1)/(b*n*(p-1)) -
  (m-n+1)/(b*n*(p-1))*Int[x^(m-n)*Sec[a+b*x^n]^(p-1),x] /;
FreeQ[{a,b,p},x] && IntegerQ[n] && GeQ[m-n,0] && NeQ[p,1]

Int[x_^m_.*Csc[a_.+b_.*x_^n_.]^p_*Cos[a_.+b_.*x_^n_.],x_Symbol] :=
  -x^(m-n+1)*Csc[a+b*x^n]^(p-1)/(b*n*(p-1)) +
  (m-n+1)/(b*n*(p-1))*Int[x^(m-n)*Csc[a+b*x^n]^(p-1),x] /;
FreeQ[{a,b,p},x] && IntegerQ[n] && GeQ[m-n,0] && NeQ[p,1]